Main list

``Template main list procedure: UiBuildMainList'' shows example main list used the in the SCOamin template:

• The main screen focus should be in the menu when first entering the application. See SaSetFocus(TCL_ADM).

• SaListShowSelectedItem(TCL_ADM) describes functions that adjust the VtList and VtDrawnList controls so that selected items are always visible within a scrolled list. This is useful when refreshing the list with a selected item. When a list is displayed, there should be an item already selected.

• Note that -autolock is used to lock the application immediately when the callback is called so processing can continue without concern for more (and possibly conflicting) events from the user.

See also:

• Template: ui.tcl, UiStart(), UiUpdateCountLabel()

Template main list procedure: UiBuildMainList

proc UiBuildMainList {form top} {
	global appvals

	# Build basic main form drawnlist widget including:
	# o Manually built title label for CHARM
	# o Drawnlist record format
	# o traditional Count label beneath the drawn list

	set labelFont medNormalFont

	# Simple drawnlist place holder widget
	set cmd {VtDrawnList $form.mainList \
			-rows 12 \
			-columns 50 \
			-rightSide FORM \
			-callback UiMainListCB \
			-defaultCallback UiMainListDoubleCB \
			-autoLock {UiMainListDoubleCB}
			}

	# Setup simple example using the "who" module
	# But for the following line, UiBuildMainList should be generic
	# and usable as is.

	if {$appvals(who)} {
		set cmd [list WhoBuildMainList $form $top]
	}

	set mainList [eval $cmd]

	UiWidgetSet mainList $mainList $form

	# Define the accompanying count label
	set countLabel [VtLabel $form.countLabel -label " " \
				-topSide NONE \
				-leftSide FORM \
				-rightSide FORM \
				-bottomSide FORM \
				-labelRight]
	UiWidgetSet countLabel $countLabel $form
	VtSetValues $mainList -bottomSide $countLabel

	# Stash the localized string "Selected" here so we only grab it once
	# from the message catalog
	UiWidgetSet selected [IntlMsg SELECTED] $countLabel
	
	# Return the bottom-most widget for further attachments
	return $countLabel
}